[Date Prev][Date Next][Thread Prev][Thread Next][Date Index][Thread Index]

Alk



Dear Friends,

In my opinion, we should not bother too much about C-13 and isotopic
fractionation when implementing the bomb and natural radiocarbon runs. This
complicates things in an unnecessary way and we will not gain more
information by analyzing a C14 run with all whistles and bells as
compared with running only C12 and fractionation corrected C14. We
should recall that our task list in GOSAC and OCMIP is quite ambitious and
that many groups are involved.  I suggest to avoid unnecessary delays
and complications.

Then, the focus should be on Ray's point 3 (and 2) and it might be
the best to prescribe surface alkalinity as realistic as possible.
My suggestion is to use Niki's fit on observed data that yields:

c                 alk=(367.5d0+54.9d0/psu*S + 0.074 kg/micormol* (O2+170*PO4) )
c                       [microeq/kg]

The salinity and phosphate fields are available (one may use annual
mean), surface oxygen can be approximated as a function of
temperature and salinity (see below).

We are right now doing some run with the 2.5-D model to investigate
the time needed to run the model to quasi steady-state and to
investigate the difference between C-14 simulations making use of
different implementations (with C13 vs. ratio carried etc)

With best regards, Fortunat

My pieces of code read:

where 
alkforc		is prescribed alkalinity in mol/m3
po4forc		is surface po4 restoring values in mol/m3
sforc		is surface salinity
rhosurf		is surface density 
(sol(i,n,j,indo2) is oxygen solubility in surface boxes


c SURFACE ALKALINITY FIELD
c-------------------------
c                 alk=(367.5d0+54.9d0/psu*S + 0.074 kg/micormol* (O2+170*PO4) )
c                       [microeq/kg]
c                       -> convert O2 and Po4 into micromol/kg,
c                       -> convert calc. alkforc into mol/m3

                  do j=1,3
                  do n=1,nt
                  do i=1,nxe(j)
                    alkforc(i,n,1,j) =
     %               ( 367.5d0+54.9d0*sforc(i,n,j)
     %                +0.074d0*(sol(i,n,j,indo2)
     %                    +170.d0*po4forc(i,n,1,j))
     %                  *1.d6/rhosurf(i,n,j) )
     %               * rhosurf(i,n,j)*1.d-6
                   do ic=2,neuph
                        alkforc(i,n,ic,j) = alkforc(i,n,1,j)
                   enddo
                  enddo
                  enddo
                  enddo

c Solubility of Oxygen
c --------------------
c       Oxygen [mol/m3(water)]
c       ------
c
c       1)units of function solo2: [solo2] = m3(STP) of o2 (gas)/ m3 of seawater
c                       (for a total atmospheric pressure of 1 atm)
c       2) conversion factor:  m3(gas)/m3(seawater) to mol/m3(seawater):
c               - using p*V(gas)=n*R*T -> n/V(gas)=p/RT  [mol/m3(gas)]
c               - STP: p=1.01325D5 Pascal , T=273.15K , R=8.3144126
c               - sol[mol/ m3(seawater)] = (p/R*T)* sol[m3(gas)STP/m3(seawater)]
c               - [p0divrt0] = mol / m3(STP)
c                  p0divrt0 = 1.01325d5/(8.3144126d0*273.15d0)=p/(R*T)
        do j=1,nb
        nxr=nxe(j)
        do nd=1,nt
        do i=1,nxr
                sol(i,nd,j,indo2) = solo2(tsurfc(i,nd,j),ssurf(i,nd,j))
     $                          *p0divrt0
        enddo
        enddo
        enddo


      double precision function solo2(tc,s)
c-------------------------------------------------------------------------------c
c     - R.F. Weiss, Deep Sea Research                                          -c
c       Vol. 17. pp. 721 to 735                                                -c
c                                                                              -c
c     "air solubility"                                                         -c
c                                                                              -c
c     - Units:                                                                 -c
c     --------                                                                 -c
c     tc   : temperature in degree celcius                                     -c
c     s    : salinity in o/oo                                                  -c
c     solo2: m3(STP) of o2 / m3 of seawater for a total atmospheric pressure   -c
c            of 1 atm.                                                         -c
c                                                                              -c
c     rem.:                                                                    -c
c     The effect of water vapore pressure and the mole                         -c
c     fraction of o2 (about 0.209) is taken into account                       -c
c     in the "air solubility". It is related to a total                        -c
c     atmospheric air-pressure of one atmosphere.                              -c
c-------------------------------------------------------------------------------c
c
      implicit none
c
c     global variables:
c     -----------------
      double precision  tc, s
c
c
c     constants:
c     ----------
      double precision a1,a2,a3,a4,b1,b2,b3
      parameter(a1=-173.4292d0, a2=249.6339d0,
     $          a3=143.3483d0, a4=-21.8492d0)
      parameter(b1=-3.3096d-2, b2=1.4259d-2, b3=-1.7d-3)
c
c     unit conversion factor:
      double precision lperml
      parameter(lperml=1.d-3)
c
c     local variables:
c     ----------------
      double precision h
c
c
      h=(tc+2.7315d2)/1.d2
      solo2=lperml*dexp(a1+a2/h+a3*dlog(h)+a4*h+s*(b1+(b2+b3*h)*h))
      end
c
c end of function "solo2"
c
- -- 
- ----------------------------------------------------------------------------
Fortunat Joos
Physics Institute, KUP, Sidlerstr. 5, CH-3012 Bern

Phone:    ++41(0)31 631 44 61
Fax:      ++41(0)31 631 44 05
e-mail:   joos@climate.unibe.ch
Internet: http://www.climate.unibe.ch/~joos/